PIC的查表程序可以利用子程序带值返回的特点来实现。具体是在主程序中先取表数据地址放入W,接着调用子程序,子程序的第一条指令将W置入PC,则程序跳到数据地址的地方,再由“RETLW”指令将数据放入W返回到主程序。下面程序以F10放表头地址。
　　　　　　MOVLW 　TABLE 　　　　;表头地址→F10 　
　　　　　　MOVWF 　10
　　　　　　　　　 ┋
　　　　　　MOVLW　 1 　　　　　　　;1→W,准备取“1”的线段值
　　　　　　ADDWF 　10,1 　　　　　;F10+W =“1”的数据地址
　　　　　　CALL　 CONVERT
　　　　　　MOVWF 　6 　　　　　　　;线段值置到B口,点亮LED
　　　　　　　　　 ┋
　　CONVERT MOVWF　 2　　　　　　　 ;W→PC TABLE
　　　　　　RETLW 　0C0H 　　　　　;“0”线段值
　　　　　　RETLW 　0F9H 　　　　　;“1”线段值
　　　　　　　　　 ┋
　　　　　　RETLW 　90H 　　　　　　;“9”线段值
　　 9)“READ……DATA,RESTORE”格式程序
　　“READ……DATA”程序是每次读取数据表的一个数据,然后将数据指针加1,准备取下一个数据。下例程序中以F10为数据表起始地址,F11做数据指针。
　　　　　　POINTER 　EQU 　11 　　;定义F11名称为POINTER
　　　　　　　　　 ┋
　　　　　　MOVLW 　　DATA
　　　　　　MOVWF 　　10 　　　　;数据表头地址→F10
　　　　　　CLRF 　　POINTER 　　;数据指针清零
　　　　　　　　　 ┋
　　　　　　MOVF 　　POINTER,0 　
　　　　　　ADDWF 10,0 　　　　　;W =F10+POINTER
　　　　　　　　　 ┋
　　　　　 INCF 　　　POINTER,1 　;指针加1
　　　　　 CALL CONVERT 　　　　　;调子程序,取表格数据
　　　　　　　　　 ┋
　　CONVERT MOVWF　　 2 　　　;数据地址→PC
　　DATA 　RETLW 　　20H 　　　;数据
　　　　　　　　　 ┋
　　　　　 RETLW 15H 　　　　　;数据
　　如果要执行“RESTORE”,只要执行一条“CLRF POINTER”即可。
　　10) 延时程序
　　如果延时时间较短,可以让程序简单地连续执行几条空操作指令“NOP”。如果延时时间长,可以用循环来实现。下例以F10计算,使循环重复执行100次。
　　　　　 MOVLW D‘100’
　　　　　 MOVWF 10
　　LOOP 　DECFSZ 10,1 　　;F10—1→F10,结果为零则跳
　　　　　 GOTO LOOP
　　　　　　 ┋
　　延时程序中计算指令执行的时间和即为延时时间。如果使用4MHz振荡,则每个指令周期为1μS。所以单周期指令时间为1μS,双周期指令时间为2μS。在上例的LOOP循环延时时间即为：（1+2）*100+2=302（μS）。在循环中插入空操作指令即可延长延时时间：
　　　　　　MOVLW 　D‘100’
　　　　　　MOVWF 　10
　　LOOP 　　NOP
　　　　　　 NOP
　　　　　　 NOP
　　　　　　DECFSZ 10,1
　　　　　　GOTO LOOP
　　　　　　　 ┋
　　延时时间=（1+1+1+1+2）*100+2=602（μS）。
　　用几个循环嵌套的方式可以大大延长延时时间。下例用2个循环来做延时：
　　　　　　MOVLW 　　D‘100’
　　　　　　MOVWF 　　10
　　LOOP　　MOVLW 　　D‘16’
　　　　　　MOVWF 　　11
　　LOOP1 　DECFSZ 　　11,1
　　　　　　GOTO 　　　LOOP1
　　　　　　DECFSZ 　　10,1
　　　　　　GOTO LOOP
　　　　　　 ┋
　　延时时间=1+1+[1+1+（1+2）*16-1+1+2]*100-1=5201（μS）
　　11) RTCC计数器的使用
　　RTCC是一个脉冲计数器,它的计数脉冲有二个来源,一个是从RTCC引脚输入的外部信号,一个是内部的指令时钟信号。可以用程序来选择其中一个信号源作为输入。RTCC可被程序用作计时之用;程序读取RTCC寄存器值以计算时间。当RTCC作为内部计时器使用时需将RTCC管脚接VDD或VSS,以减少干扰和耗电流。下例程序以RTCC做延时：
　　　　　　RTCC 　EQU 　1
　　　　　　 ┋
　　　　　　CLRF 　RTCC 　　　;RTCC清0
　　　　　　MOVLW 　07H
　　　　　　OPTION 　　　;选择预设倍数1：256→RTCC
　　 LOOP 　MOVLW 　255 　　;RTCC计数终值
　　　　　　SUBWF 　RTCC,0
　　　　　　BTFSS STATUS,Z 　　;RTCC=255？
　　　　　　GOTO LOOP
　　　　　　　┋
　　这个延时程序中,每过256个指令周期RTCC寄存器增1（分频比=1：256）,设芯片使用4MHz振荡,则：
　　延时时间=256*256=65536（μS）
　　RTCC是自振式的,在它计数时,程序可以去做别的事情,只要隔一段时间去读取它,检测它的计数值即可。
　　12) 寄存器体（BANK）的寻址
　　对于PIC16C54/55/56,寄存器有32个,只有一个体（BANK）,故不存在体寻址问题,对于PIC16C57/58来说,寄存器则有80个,分为4个体（BANK0-BANK3）。在对F4（FSR）的说明中可知,F4的bit6和bit5是寄存器体寻址位,其对应关系如下：

Bit6 　Bit5	BANK	物理地址
0　 　　0	BANK 0	10H～1FH
0 　　　1	BANK 1	30H～3FH
1 　　　0	BANK 2	50H～5FH
1　　　 1	BANK 3	70H～7FH

当芯片上电RESET后,F4的bit6,bit5是随机的,非上电的RESET则保持原先状态不变。
　　下面的例子对BANK1和BANK2的30H及50H寄存器写入数据。
　　例1．（设目前体选为BANK0）
　　　　　　BSF　　 4,5　　　 ;置位bit5=1,选择BANK1
　　　　　　MOVLW　 DATA
　　　　　　MOVWF 　10H 　　　; DATA→30H
　　　　　　BCF　　 4,5
　　　　　　BSF 　　4,6 　　;bit6=1,bit5=0选择BANK2
　　　　　　MOVWF 　10H 　　　;DATA→50H
　　从上例中我们看到,对某一体（BANK）中的寄存器进行读写,首先要先对F4中的体寻址位进行操作。实际应用中一般上电复位后先清F4的bit6和bit5为0,使之指向BANK0,以后再根据需要使其指向相应的体。
　　注意,在例子中对30H寄存器（BANK1）和50H寄存器（BANK2）写数时,用的指令“MOVWF 10H”中寄存器地址写的都是“10H”,而不是读者预期的“MOVWF 30H”和“MOVWF 50H”,为什么？
　　让我们回顾一下指令表。在PIC16C5X的所有有关寄存器的指令码中,寄存寻址位都只占5个位：fffff,只能寻址32个（00H—1FH）寄存器。所以要选址80个寄存器,还要再用二位体选址位PA1和PA0。当我们设置好体寻址位PA1和PA0,使之指向一个BANK,那么指令“MOVWF 10H”就是将W内容置入这个BANK中的相应寄存器内（10H,30H,50H,或70H）。
　　有些设计者第一次接触体选址的概念,难免理解上有出入,下面是一个例子：
　　例2：（设目前体选为BANK0）
　　　　　　MOVLW 　55H　
　　　　　　MOVWF 　30H 　　;欲把55H→30H寄存器
　　　　　　MOVLW 　66H
　　　　　　MOVWF 　50H 　　;欲把66H→50H寄存器
　　以为“MOVWF 30H”一定能把W置入30H,“MOVWF 50H”一定能把W置入50H,这是错误的。因为这两条指令的实际效果是“MOVWF 10H”,原因上面已经说明过了。所以例2这段程序最后结果是F10H=66H,而真正的F30H和F50H并没有被操作到。
　　建议：为使体选址的程序清晰明了,建议多用名称定义符来写程序,则不易混淆。 　　例3：假设在程序中用到BANK0,BANK1,BANK2的几个寄存器如下：

BANK0	地址	BANK1	地址	BANK2	地址	BANK3	地址
A	10H	B	30H	C	50H	·	70H
·	·	·	·	·	·	·	·
·	·	·	·	·	·	·	·